设为首页收藏本站淘宝杂货铺

从F到0 - From F to 0

 找回密码
 注册已关闭
搜索
查看: 2695|回复: 2
收起左侧

易语言实现计算一个大文件的crc64校验值 crc64_file(); 可指定缓存大小,纯核心库实现

[复制链接]
发表于 2019-6-11 10:00:51 | 显示全部楼层 |阅读模式

  1. .版本 2

  2. .程序集 程序集1
  3. .程序集变量 CRC64表格, 长整数型, , "256"
  4. .程序集变量 CRC64常数, 长整数型, , "3"

  5. .子程序 _启动子程序, 整数型, , 请在本子程序中放置易模块初始化代码

  6. 初始化CRC64 ()
  7. _临时子程序 ()  ' 在初始化代码执行完毕后调用测试代码
  8. 返回 (0)  ' 可以根据您的需要返回任意数值

  9. .子程序 初始化CRC64
  10. .局部变量 i, 整数型
  11. .局部变量 crc, 长整数型

  12. CRC64常数 [1] = 取字节集数据 ({ 255, 255, 255, 255, 255, 255, 255, 127 }, #长整数型, )
  13. CRC64常数 [2] = 取字节集数据 ({ 66, 15, 135, 215, 149, 87, 108, 201 }, #长整数型, )
  14. CRC64常数 [3] = 取字节集数据 ({ 255, 255, 255, 255, 255, 255, 255, 0 }, #长整数型, )
  15. .变量循环首 (0, 255, 1, i)
  16.     crc = i
  17.     .计次循环首 (8, )
  18.         crc = 长整数位异或 (长整数位与 (长整数右移 (crc, 1), CRC64常数 [1]), 选择 (长整数位与 (crc, 1) = 1, CRC64常数 [2], 0))
  19.     .计次循环尾 ()
  20.     CRC64表格 [i + 1] = crc
  21. .变量循环尾 ()


  22. .子程序 长整数右移, 长整数型
  23. .参数 值, 长整数型
  24. .参数 位数, 整数型

  25. 置入代码 ({ 139, 69, 8, 139, 85, 12, 139, 77, 16, 128, 249, 64, 115, 14, 128, 249, 32, 115, 16, 15, 173, 208, 211, 250, 201, 194, 12, 0, 193, 250, 31, 137, 208, 235, 245, 137, 208, 193, 250, 31, 128, 225, 31, 211, 248, 235, 233 })
  26. 返回 (0)

  27. .子程序 长整数位与, 长整数型
  28. .参数 值1, 长整数型
  29. .参数 值2, 长整数型

  30. 置入代码 ({ 139, 69, 8, 139, 85, 12, 35, 69, 16, 35, 85, 20, 201, 194, 16, 0 })
  31. 返回 (0)

  32. .子程序 长整数位异或, 长整数型
  33. .参数 值1, 长整数型
  34. .参数 值2, 长整数型

  35. 置入代码 ({ 139, 69, 8, 139, 85, 12, 51, 69, 16, 51, 85, 20, 201, 194, 16, 0 })
  36. 返回 (0)

  37. .子程序 长整数位取反, 长整数型
  38. .参数 值, 长整数型

  39. 置入代码 ({ 139, 69, 8, 139, 85, 12, 247, 208, 247, 210, 201, 194, 8, 0 })
  40. 返回 (0)

  41. .子程序 _临时子程序
  42. .局部变量 失败, 逻辑型

  43. ' 本名称子程序用作测试程序用,仅在开发及调试环境中有效,编译发布程序前将被系统自动清空,请将所有用作测试的临时代码放在本子程序中。 ***注意不要修改本子程序的名称、参数及返回值类型。
  44. 输出调试文本 (CRC64_文件 (“data.bin”, 失败, ))
  45. 输出调试文本 (失败)

  46. .子程序 CRC64_文件, 长整数型, 公开
  47. .参数 文件名, 文本型, , 文件路径或文件名
  48. .参数 失败, 逻辑型, 参考 可空, 计算失败传出真,成功为假
  49. .参数 缓存容量, 整数型, 可空, 单位字节,留空默认1Mb
  50. .局部变量 分段, 字节集
  51. .局部变量 长度, 整数型
  52. .局部变量 crc, 长整数型
  53. .局部变量 计数, 整数型
  54. .局部变量 文件号, 整数型

  55. .如果真 (缓存容量 ≤ 0)
  56.     缓存容量 = 1048576
  57. .如果真结束
  58. 文件号 = 打开文件 (文件名, 1, 3)
  59. .如果真 (文件号 = 0)
  60.     失败 = 真
  61.     返回 (0)
  62. .如果真结束
  63. crc = -1
  64. .判断循环首 (真)
  65.     分段 = 读入字节集 (文件号, 缓存容量)
  66.     长度 = 取字节集长度 (分段)
  67.     .如果 (长度 = 0)
  68.         跳出循环 ()
  69.     .否则
  70.         .计次循环首 (长度, 计数)
  71.             crc = 长整数位异或 (CRC64表格 [长整数位与 (长整数位异或 (crc, 分段 [计数]), 255) + 1], 长整数位与 (长整数右移 (crc, 8), CRC64常数 [3]))

  72.         .计次循环尾 ()

  73.     .如果结束

  74. .判断循环尾 ()
  75. 关闭文件 (文件号)
  76. 失败 = 假
  77. 返回 (长整数位取反 (crc))

复制代码

相关帖子

发表于 2019-6-11 11:29:39 | 显示全部楼层
  1. 谢谢分享
复制代码
发表于 2019-6-12 10:33:48 | 显示全部楼层
路过打酱油
您需要登录后才可以回帖 登录 | 注册已关闭

本版积分规则

QQ|手机版|Archiver|从F到0 ( 蒙ICP备17002595号-1 )
蒙公网安备15010402000325号

腾讯云安全认证

GMT+8, 2024-3-29 08:45 , Processed in 0.465026 second(s), 20 queries .

Powered by Discuz! X3.4 Licensed

Copyright © 2001-2021, Tencent Cloud.

快速回复 返回顶部 返回列表