设为首页收藏本站帮助中心
查看: 117|回复: 0
收起左侧

易语言 删除文件增强版 保密文件的填充随机数据擦除 以防止数据恢复找回 (返回逻辑型)

[复制链接]
发表于 2023-9-23 18:44:24 | 显示全部楼层 |阅读模式
本帖最后由 CNWTEPRG 于 2023-9-23 18:45 编辑

1.png
  1. .版本 2

  2. .程序集 程序集1

  3. .子程序 _启动子程序, 整数型, , 请在本子程序中放置易模块初始化代码

  4. 置随机数种子 ()
  5. _临时子程序 ()  ' 在初始化代码执行完毕后调用测试代码
  6. 返回 (0)  ' 可以根据您的需要返回任意数值

  7. .子程序 _临时子程序

  8. ' 本名称子程序用作测试程序用,仅在开发及调试环境中有效,编译发布程序前将被系统自动清空,请将所有用作测试的临时代码放在本子程序中。 ***注意不要修改本子程序的名称、参数及返回值类型。
  9. 信息框 (删除文件_防止恢复 (“file.txt”), 0, , )

  10. .子程序 删除文件_防止恢复, 逻辑型, 公开, 删除前填充随机数据擦除文件 防止数据恢复软件找回文件数据 (成功返回真,失败返回假)
  11. .参数 欲删除的文件名, 文本型, , 适用于保密文件删除
  12. .参数 文件擦除次数, 字节型, 可空, 擦除次数:1~255 0:不擦除,留空默认为1
  13. .参数 缓存容量, 整数型, 可空, 一次处理多少字节,留空默认1Mb
  14. .局部变量 文件号, 整数型
  15. .局部变量 长度, 整数型

  16. .如果真 (置文件属性 (欲删除的文件名, #隐藏文件) = 假)
  17.     返回 (假)
  18. .如果真结束
  19. .如果真 (缓存容量 ≤ 0)
  20.     缓存容量 = 1048576
  21. .如果真结束
  22. .如果真 (是否为空 (文件擦除次数))
  23.     文件擦除次数 = 1
  24. .如果真结束
  25. .如果真 (文件擦除次数 > 0)
  26.     文件号 = 打开文件 (欲删除的文件名, #读写, #禁止读写)
  27.     .如果真 (文件号 = 0)
  28.         返回 (假)
  29.     .如果真结束
  30.     .计次循环首 (文件擦除次数, )
  31.         .如果真 (移动读写位置 (文件号, #文件首, 0) = 假)
  32.             返回 (假)
  33.         .如果真结束
  34.         .循环判断首 ()
  35.             长度 = 取字节集长度 (读入字节集 (文件号, 缓存容量))
  36.             .判断开始 (长度 = 0)
  37.                 跳出循环 ()
  38.             .判断 (移动读写位置 (文件号, #现行位置, -长度) = 假)
  39.                 跳出循环 ()
  40.             .判断 (写出字节集 (文件号, 取随机字节集 (长度)) = 假)
  41.                 跳出循环 ()
  42.             .默认

  43.             .判断结束

  44.         .循环判断尾 (真)
  45.     .计次循环尾 ()
  46.     关闭文件 (文件号)
  47. .如果真结束
  48. 返回 (删除文件 (欲删除的文件名))

  49. .子程序 取随机字节集, 字节集
  50. .参数 长度, 整数型
  51. .局部变量 字节集, 字节集
  52. .局部变量 计数, 整数型

  53. 字节集 = 取空白字节集 (长度)
  54. .计次循环首 (长度, 计数)
  55.     字节集 [计数] = 取随机数 (0, 255)
  56. .计次循环尾 ()
  57. 返回 (字节集)
复制代码

相关帖子

回复

使用道具 举报

您需要登录后才可以回帖 登录 | 加入我们

本版积分规则